(x^5) +15 x + 12 の厳密解  with Mathematica 13.3

2025 年2月   by    (HyperlinkURL["mixedmoss", https://mixedmoss.com])

「FindGaloisGroup.nb」で最後から2番目に書いた「StepByStep Mathematica Program 」を 5次向けに直し，それを使って求めます．もちろん 最後に挙げた「Automated Mathematica Program」 の方を使うとすぐ求まりますが，それでは説明になりません．いまさら「説明は不要」という方は C5_Solutions.nb/pdf を御覧ください．逆に，より詳しい説明は「FindGaloisGroup.nb/pdf」をご覧ください．

【注】余りにも長いので結果を一部しか表示していません．全ての結果が欲しい方は Mathematica  を使って ノートブックを開いてください．また「F20_Solution . nb/pdf 」には，原始元による全ての解の表現が小さいフォントで載せてあります．

Step1 . 分解方程式

(出力は 120次の方程式R (x)を因数分解した式, そして分解方程式V(x)です．分解方程式はR(x)の他の因子を選んでも大丈夫です)

ClearAll["`*"];
f[x_] = x^5 +15 x + 12;
vars={α,β,γ,δ,ϵ};
vs=Permutations[vars].{1,4,3,2,5};(*R(x)に重解があるときはここを変える*)
coef=CoefficientList[f[x],x]//Reverse//Drop[#,1]&;
{s1,s2,s3,s4,s5}=Table[SymmetricPolynomial[i,vars],{i,1,5}];
contents={s1+coef[[1]],s2-coef[[2]],s3+coef[[3]],s4-coef[[4]],s5+coef[[5]],v−vs[[1]]};
GroebnerBasis[contents,{α,β,γ,δ,ϵ,v}][[1]];
Factor[%]
V[x_]=(List@@%)[[1]]/.{v->x}

Step2 . f (x)の解を原始元vで表す

GroebnerBasis[contents,{α,v},{β,γ,δ,ϵ}]//PolynomialMod[Last[#],V[v]]&;
α'=α/.Solve[%==0,α][[1]]//Collect[#,v]&;
GroebnerBasis[contents,{β,v},{α,γ,δ,ϵ}]//PolynomialMod[Last[#],V[v]]&;
β'=β/.Solve[%==0,β][[1]]//Collect[#,v]&;
GroebnerBasis[contents,{γ,v},{α,β,δ,ϵ}]//PolynomialMod[Last[#],V[v]]&;
γ'=γ/.Solve[%==0,γ][[1]]//Collect[#,v]&;
GroebnerBasis[contents,{δ,v},{α,β,γ,ϵ}]//PolynomialMod[Last[#],V[v]]&;
δ'=δ/.Solve[%==0,δ][[1]]//Collect[#,v]&;
GroebnerBasis[contents,{ϵ,v},{α,β,γ,δ}]//PolynomialMod[Last[#],V[v]]&;
ϵ'=ϵ/.Solve[%==0,ϵ][[1]]//Collect[#,v]&;
{α',⋯⋯⋯}

Step３ . V(x)の解を原始元vで表す

vs/.{α->α',β->β',γ->γ',δ->δ',ϵ->ϵ'}//Simplify;(*vsの要素をvで表す*)
PolynomialMod[V[#],V[v]]&/@%;
Position[%,0]//Flatten
vset=vs[[%]]/.{α->α',β->β',γ->γ',δ->δ',ϵ->ϵ'}//Collect[#,v]&;
vset//Short

Step4 . Galois群を求める

sols={α',β',γ',δ',ϵ'};
Table[
perm=sols/.{vset[[1]]->vset[[i]]}//PolynomialMod[#,V[v]]&;
Table[FirstPosition[Simplify[perm-sols[[k]]{1,1,1,1,1}],0][[1]],{k,1,5}]//Flatten,{i,1,Length[vset]}];
MatrixForm[%]

上はガロア流の表現．現代の書き方に直すと次の様になる．
Gal={Id, (2,4,5,3), (2,3,5,4), (2,5)(3,4), (1,2)(3,5), (1,5,4,3,2),
 (1,3,4,2), (1,4,5,2), (1,2,4,3), (1,3)(4,5), (1,4,2,5,3), (1,5,2,3), (1,2,5,4),
 (1,5,3,4), (1,4)(2,3), (1,3,5,2,4), (1,2,3,4,5), (1,4,3,5), (1,3,2,5), (1,5)(2,4)}

ここでσ=(1,2,3,4,5),τ=(2,3,4,5)とおくと，(σ^5)=   (τ^4) =Id だから
Gal={Id, (τ^3), τ, (τ^2), (τ^2) (σ^4), (σ^4),(τ^3) (σ^4),τ (σ^4),(τ^2) (σ^3), (σ^3), (τ^3) (σ^3),(τ^3) (σ^2),τ (σ^2), (τ^2) (σ^2),  (σ^2), σ, (τ^3) σ,τ σ,(τ^2) σ}=<τ,σ>≃ (Subscript[C, 4]) (Subscript[C, 5])

このように (Subscript[C, 4]) (Subscript[C, 5])の形で書ける群を (Subscript[F, 20])(フロベニウス群)というらしい．
分解列は   (Subscript[F, 20])⊳ (Subscript[D, 5]) ⊳ (Subscript[C, 5]) ⊳ {Id}  
ただし (Subscript[C, n])は巡回群，(Subscript[D, n ])は2面体群で
 (Subscript[C, 5])=<σ>, (Subscript[D, 5])=(Subscript[C, 5])+(τ^2)(Subscript[C, 5])
 (Subscript[F, 20])= (Subscript[D, 5])+τ(Subscript[D, 5])=(Subscript[C, 5])+τ(Subscript[C, 5])+(τ^2)(Subscript[C, 5])+(τ^3)(Subscript[C, 5])≃ (Subscript[C, 4]) (Subscript[C, 5])

[part2 . (HyperlinkURL["F20_Solution.nb", https://mixedmoss.com/mathematica/Galois/notebook/F20_Solutions.nb]) （厳密解を求める)  に続く］